Komponen-komponen yang dipakai pada aplikasi ini yaitu komponen CommonDialog yang terdapat pada
kontrol Microsoft Common Dialog Control (comdlg32.ocx). Sedangkan reference yang dibutuhkan ada
dua macam yaitu Microsoft ActiveX Data Objects 2.x Library (bisa 2.1 atau yang diatasnya) (msado21.tlb) dan
Microsoft OLE DB Service Component 1.0 Type Library.
Pada program ini dibutuhkan sebuah form (frmMain) dan sebuah module (modUDL).module nya Anda bisa lihat pada source code.
Pada module inilah berisi rutin-rutin penting untung memanipulasi file UDL yaitu:
1. Function CreateUDL() as boolean
Fungsi ini berguna untuk menampilkan dialog UDL dan melalui dialog UDL ini Anda bisa membuat
sebuah connection string baru yang berbasis wizard. Adapun code-nya adalah sebagai berikut:
Public Function CreateUDL() As Boolean
On Error GoTo Err_CreateUDL
Dim DataLink As New MSDASC.DataLinks
Dim Conn As ADODB.Connection
Set Conn = DataLink.PromptNew
Conn.Open
ADOConnectString = Conn.ConnectionString
Conn.Close
CreateUDL = True
Exit Function
Err_CreateUDL:
CreateUDL = False
End Function
2. Procedure SaveUDLFile(byval UDLFile as string)
Procedure ini berguna untuk menyimpan connection string yang sudah dibuat dengan fungsi CreateUDL
di atas ke dalam format file UDL. File UDL adalah file text biasa hanya saja isinya adalah string dengan
format unicode. Adapun code-nya adalah sebagai berikut:
Public Sub SaveUDLFile(ByVal UDLFile As String)
Dim UDLContent As String, intFileNum As Integer
UDLContent = UDL_HEADER_1 & vbCrLf & _
UDL_HEADER_2 & vbCrLf & _
ADOConnectString
UDLContent = StrConv(UDLContent, vbUnicode)
intFileNum = FreeFile
If Dir(UDLFile) <> vbNullString Then Kill UDLFile
Open UDLFile For Binary As #intFileNum
Put #intFileNum, , UDLContent
Close #intFileNum
End Sub
3. Function LoadUDLFile(byval UDLFile as string) as boolean
Fungsi ini berguna untuk me-load file UDL dan mengambil connection string di dalam file UDL tadi.
Adapun code-nya adalah sebagai berikut:
Public Function LoadUDLFile(ByVal UDLFile As String) As Boolean
Dim intFileNum As Integer, UDLContent As String
Dim i As Integer
intFileNum = FreeFile
Open UDLFile For Binary As #intFileNum
UDLContent = Input(LOF(intFileNum), #intFileNum)
Close #intFileNum
UDLContent = StrConv(UDLContent, vbFromUnicode)
i = InStr(UDLContent, "Provider=")
If i > 0 Then
ADOConnectString = Mid(UDLContent, i)
LoadUDLFile = True
Else
LoadUDLFile = False
End If
End Function
4. Function ApplyToUDLFile(optional byval ConnectString as string) as string
Fungsi ini berguna untuk meng-apply connection string yang sudah didapat dari fungsi LoadUDLFile
diatas kedalam dialog UDL untuk diedit lebih lanjut. Adapun code-nya adalah sebagai berikut:
Public Function ApplyToUDLDialog(Optional ByVal ConnectString As
String) As Boolean
On Error GoTo Err_OpenUDL
Dim DataLink As New MSDASC.DataLinks
Dim Conn As New ADODB.Connection
If ADOConnectString = vbNullString Then
ApplyToUDLDialog = CreateUDL
Exit Function
Else
Conn.ConnectionString = ADOConnectString
If DataLink.PromptEdit(Conn) Then
Conn.Open
ADOConnectString = Conn.ConnectionString
Conn.Close
End If
End If
ApplyToUDLDialog = True
Exit Function
Err_OpenUDL:
ApplyToUDLDialog = False
End Function
Nah, selanjutnya silakan saja Anda buka source code lengkap yang diberikan oleh penulis dibawah ini
dan cobalah bermain-main dengannya ;)
Source code UDL Manipulator bisa anda download di
http://ilmukomputer.com/tipstrik/pemrograman/udlm.zip
(Source:ilmukomputer.com)
(penulis:sonyarianto)
Posts
0 comments:
Post a Comment